// Make a moving 2d background
// http://forum.imagej.net/t/generating-synthetic-data-2d-surface/11318
// Dave Mason 

imageDim=256;     //-- Set image dimension in pixels
numSpots=150;     //-- Number of spots in the field
spotDiam=50;      //-- how big (in pixels) should the spot be
blurRatio=0.2;     //-- relationship between particle size and Gaussian kernel
frames=50;		  //-- how many images do you want
wiggleDist=5;	  //-- full range for wiggle distance

//-- Make a new image
newImage("Example", "8-bit grayscale-mode black", imageDim, imageDim, 1,1,frames);
//run("Add...", "value=128"); //-- uncomment if you want minima and maxima

//-- Create random spots
for (i=0;i<numSpots;i++){
//-- pick a random intensity for this spot between 10 and 245
randomIntensity=10+floor(random*235);
setForegroundColor(randomIntensity,randomIntensity,randomIntensity);

xPos=newArray(frames);
yPos=newArray(frames);

//-- pick a start position
xPos[0]=floor(random*imageDim);
yPos[0]=floor(random*imageDim);

//-- Calculate the position after wiggling for each frame
for (j=1;j<frames;j++){
	xPos[j]=xPos[j-1]+randn()*wiggleDist;
	yPos[j]=yPos[j-1]+randn()*wiggleDist;
	}

//-- Now draw in the spots
for (j=0;j<frames;j++){
setSlice(j+1);	
makeOval(xPos[j], yPos[j], spotDiam, spotDiam);     
//-- Draw the point into the image (using foreground colour)
run("Fill", "slice");
//-- Deselect everything
run("Select None");
}

} //-- spot loop

//-- now we have spots, blur and (if required) noise it up a bit
run("Gaussian Blur...", "sigma="+floor(spotDiam*blurRatio)+" stack");
//run("Add Noise");
run("Enhance Contrast...", "saturated=0");


//-- Functions

function randn() {
	//-- Use the Box-Muller method to produce normally distributed random numbers
	U=random();
	V=random();
	return sqrt(-2*log(U))*cos(2*3.14*V);
}